Windows updates not working

[DigitalAardvark]

Hi
Is there anybody on here who can help me.
I'm not a computer expert but of reasonable intelligence.
It has come to light that my daughters laptap has not been software updating.
I can look in the history back to 21/03/17 and all updates have failed.
I have been trying to get updates going over the last couple of weeks and each time after the restart it has said that windows has updated.
I have virtually no restore points except for the last couple of weeks when I have been interferring with the update process.
God knows how long its not been updating.
The laptop is about 3 years old was Win 8 when bought and I updated to win 10. It has at times been a nightmare after the upgrade to 10 and bits not working.
On the microsoft site with the laptops symptoms they seem to be pushing me towards a clean Win10 install.
I desparately do not want to do this, its been such a nightmare since upgrading the operting system.

Is there anybody here who could advise me how to get the laptop updating.

Thanks

[twol]

Try these, the 1st was used frequently with the early Windows 10 Insider builds
Where you basically stop windows update, delete the installed cache and then restart.
The 2nd is a microsoft fix for an early issue that effected "normal" (non insider) users

http://www.thewindowsclub.com/software-distribution-folder-in-windows

https://www.microsoft.com/en-us/download/details.aspx?id=53942

If you try the 1st one, you need to get in quick when Win10 boots, before windows update starts processing!

[bsmith1]

I use a script I got from Microsoft I use @ work, if forces a remove of any failed updates then re-downloads windows updates.

Copy the following in to notepad and save it a resetWU.cmd and save to c:\



@echo off
cls
@echo 1. Stopping Windows Update, BITS, Application Identity, Cryptographic Services and SMS Host Agent services...
net stop wuauserv
net stop bits
net stop appidsvc
net stop cryptsvc
net stop ccmexec

@echo 2. Checking if services were stopped successfully...
sc query wuauserv | findstr /I /C:"STOPPED"
if %errorlevel% NEQ 0 goto END

sc query bits | findstr /I /C:"STOPPED"
if %errorlevel% NEQ 0 goto END

sc query appidsvc | findstr /I /C:"STOPPED"
if %errorlevel% NEQ 0 sc query appidsvc | findstr /I /C:"OpenService FAILED 1060"
if %errorlevel% NEQ 0 goto END

sc query cryptsvc | findstr /I /C:"STOPPED"
if %errorlevel% NEQ 0 goto END

sc query ccmexec | findstr /I /C:"STOPPED"
if %errorlevel% NEQ 0 sc query ccmexec | findstr /I /C:"OpenService FAILED 1060"
if %errorlevel% NEQ 0 goto END

@echo 3. Deleting AU cache folder and log file...
del /f /q "%ALLUSERSPROFILE%\Application Data\Microsoft\Network\Downloader\qmgr*.dat"
del /f /s /q %SystemRoot%\SoftwareDistribution\*.*
del /f /s /q %SystemRoot%\system32\catroot2\*.*
del /f /q %SystemRoot%\WindowsUpdate.log

@echo 4. Re-registering DLL files...
cd /d %WinDir%\system32
regsvr32.exe /s atl.dll
regsvr32.exe /s urlmon.dll
regsvr32.exe /s mshtml.dll
regsvr32.exe /s shdocvw.dll
regsvr32.exe /s browseui.dll
regsvr32.exe /s jscript.dll
regsvr32.exe /s vbscript.dll
regsvr32.exe /s scrrun.dll
regsvr32.exe /s msxml.dll
regsvr32.exe /s msxml3.dll
regsvr32.exe /s msxml6.dll
regsvr32.exe /s actxprxy.dll
regsvr32.exe /s softpub.dll
regsvr32.exe /s wintrust.dll
regsvr32.exe /s dssenh.dll
regsvr32.exe /s rsaenh.dll
regsvr32.exe /s gpkcsp.dll
regsvr32.exe /s sccbase.dll
regsvr32.exe /s slbcsp.dll
regsvr32.exe /s cryptdlg.dll
regsvr32.exe /s oleaut32.dll
regsvr32.exe /s ole32.dll
regsvr32.exe /s shell32.dll
regsvr32.exe /s initpki.dll
regsvr32.exe /s wuapi.dll
regsvr32.exe /s wuaueng.dll
regsvr32.exe /s wuaueng1.dll
regsvr32.exe /s wucltui.dll
regsvr32.exe /s wups.dll
regsvr32.exe /s wups2.dll
regsvr32.exe /s wuweb.dll
regsvr32.exe /s qmgr.dll
regsvr32.exe /s qmgrprxy.dll
regsvr32.exe /s wucltux.dll
regsvr32.exe /s muweb.dll
regsvr32.exe /s wuwebv.dll

@echo 5. Removing WSUS Client Id...
REG DELETE "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Win dowsUpdate" /v AccountDomainSid /f
REG DELETE "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Win dowsUpdate" /v PingID /f
REG DELETE "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Win dowsUpdate" /v SusClientId /f

@echo 6. Resetting Winsock and WinHTTP Proxy...
netsh winsock reset
proxycfg.exe -d
netsh winhttp reset proxy

@echo 7. Cryptographic Services, Application Identity, BITS, Windows Update services...
net start cryptsvc
net start appidsvc
net start bits
net start wuauserv

@echo 8. Deleting all BITS jobs...
bitsadmin.exe /reset /allusers

@echo 9. Forcing AU discovery...
wuauclt /resetauthorization /detectnow

:END



Type CMD in the search box and right click to run as admin, type cd c:\

Type resetWU.cmd

if it does not run all 9 steps and stops, press up arrow and enter to rerun command

You can make windows updates install using a windows command

wuauclt /updatenow